Microsoft DirectX 9.0 SDK (December 2004)
シェーダーモデル 3.0
|
|
Microsoft Visual Studio .NET 2003 Microsoft DirectX 9.0 SDK (December 2004) シェーダーモデル 3.0 |
| ■２．５Ｄ モーションブラー | Prev Top Next |
| 関連ページ：ランバート拡散照明 |
今回は、２．５Ｄ モーションブラーというものをやります。元ネタは「GameWatch」の「ロストプラネット」の記事です。 他にもMonsho氏のもんしょの巣穴とかPocol氏のProject ASURAとかあちこちで紹介されているので今更なんですけどね。 というわけで(どんなわけで？)２．５Ｄ モーションブラーに関する解説は他のサイトを参照してください(手抜きですまん)。
カメラの平行移動とティーポットの平行移動によるアニメーションです。カメラは本当は回転してるんだけど、まあ左に平行移動(シーン全体が右に平行移動)していると思ってください。
ティーポットは左に平行移動しています。X方向にブラーがかかっているのがわかると思います。
では実装概念です。
１．シーンをレンダーターゲットサーフェイスにレンダリングします。
２．速度マップの作成します。
３．速度マップを参照しブラー処理をかけます。
速度マップの作成は、頂点シェーダーでモデルを引き伸ばし、過去の頂点の座標 → 現在の頂点の座標 のベクトルを計算しこれを速度としてピクセルシェーダーで出力するみたいなことをやります。 詳細は他のサイトを参照してください。
---MotionBlur.fx---
float4x4 m_WVPNew; //現在のワールド空間のワールド×ビュー×射影
float4x4 m_WVPOld; //過去のワールド空間のワールド×ビュー×射影
float4x4 m_ROnly; //法線ベクトルをワールド空間上で変換するための行列。法線ベクトルなので回転成分のみ。
sampler tex0 : register(s0); //シーンのレンダリングイメージ。Pass1で使用する。
sampler tex1 : register(s1); //速度マップ。Pass1で使用する。
//速度マップを作成
struct VS_CreateVMap_OUTPUT
{
float4 Pos : POSITION;
float4 Dir : TEXCOORD0; //速度ベクトル
};
VS_CreateVMap_OUTPUT VS_CreateVMap( float4 Pos : POSITION,
float4 Normal : NORMAL,
float2 Tex : TEXCOORD0 )
{
VS_CreateVMap_OUTPUT Out;
//法線ベクトルは回転成分のみの行列を適応すること
float3 N = mul( Normal.xyz, m_ROnly );
//現在の頂点の座標
float4 NewPos = mul( Pos, m_WVPNew );
//過去の頂点の座標
float4 OldPos = mul( Pos, m_WVPOld );
//頂点の移動方向ベクトル
float3 Dir = NewPos.xyz - OldPos.xyz;
//頂点の移動方向ベクトルと頂点の法線の内積を計算
float a = dot( normalize( Dir ), normalize( N ) );
//過去の方向にモデルを引き伸ばす
if( a < 0.0f )
Out.Pos = OldPos;
else
Out.Pos = NewPos;
//速度ベクトルの計算
//-1.0f から 1.0f の範囲をテクスチャー座標系の 0.0f 〜 1.0f のテクセル位置を参照するため距離を半分にする
Out.Dir.xy = ( NewPos.xy / NewPos.w - OldPos.xy / OldPos.w ) * 0.5f;
//最終的にテクセルのオフセット値となるため Y方向 を逆向きにする
Out.Dir.y *= -1.0f;
//シーンのＺ値を計算するためのパラメータ
Out.Dir.z = Out.Pos.z;
Out.Dir.w = Out.Pos.w;
return Out;
}
float4 PS_CreateVMap( VS_CreateVMap_OUTPUT In ) : COLOR0
{
float4 Out;
//速度ベクトル
Out.xy = In.Dir.xy;
//未使用
Out.z = 1.0f;
//Ｚ値を計算
Out.w = In.Dir.z / In.Dir.w;
return Out;
}
//速度マップを参照してブラー処理
struct VS_Final_OUTPUT
{
float4 Pos : POSITION;
float2 Tex : TEXCOORD0;
};
VS_Final_OUTPUT VS_Final( float4 Pos : POSITION,
float4 COLOR0 : COLOR0,
float2 Tex : TEXCOORD0 )
{
VS_Final_OUTPUT Out;
Out.Pos = Pos;
Out.Tex = Tex;
return Out;
}
float4 PS_Final( VS_Final_OUTPUT In ) : COLOR0
{
//ボケのなめらかさ。数値を大きくすると滑らかになる。
int Blur = 10;
//速度マップから速度ベクトルとＺ値を取得
float4 Velocity = tex2D( tex1, In.Tex );
Velocity.xy /= (float)Blur;
int cnt = 1;
float4 BColor;
//シーンのレンダリングイメージを取得。a成分にＺ値が格納される。
float4 Out = tex2D( tex0, In.Tex );
for( int i=cnt; i<Blur; i++ )
{
//速度ベクトルの方向のテクセル位置を参照し、シーンのレンダリングイメージの色情報を取得する。
BColor = tex2D( tex0, In.Tex + Velocity.xy * (float)i );
//速度マップのＺ値と速度ベクトル方向にあるテクセル位置をサンプリングしたシーンのレンダリングイメージのＺ値を比較する。(注意１)
if( Velocity.a < BColor.a + 0.04f )
{
cnt++;
Out += BColor;
}
}
Out /= (float)cnt;
return Out;
}
technique TShader
{
//速度マップ作成
pass P0
{
VertexShader = compile vs_1_1 VS_CreateVMap();
PixelShader = compile ps_2_0 PS_CreateVMap();
}
//ブラー処理
pass P1
{
VertexShader = compile vs_1_1 VS_Final();
PixelShader = compile ps_3_0 PS_Final();
}
}
Pass0で速度マップを作成し、Pass1でブラー処理を行います。ちなみにSM 3.0でないとコンパイルできないので注意してください。
(注意１) Ｚ値の比較を行い、ブラー処理を切捨ててます。この処理が必要な理由は「GameWatch」の「ロストプラネット」の記事で詳しく説明されているので
そちらを参照してください。0.04fはバイアス値です。アプリケーションごとに調整してください。
ちなみにＺ値の比較を行わないとこうなります。
ティーポットの左側の輪郭部分が黒くなり、正しくレンダリングされていないのがわかると思います。
---MotionBlur.h---
//D3D2DSQUAREは2Dオブジェクト。詳細は表面化散乱(Subsurface Scattering) を参照
class MOTION_BLUR : public D3D2DSQUARE
{
private:
LPD3DXEFFECT m_pEffect;
D3DXHANDLE m_pTechnique, m_pWVPNew, m_pWVPOld, m_pROnly;
D3DXMATRIX m_matViewNew, m_matViewOld, m_matProj;
LPDIRECT3DDEVICE9 m_pd3dDevice;
D3DPRESENT_PARAMETERS* m_pd3dParameters;
public:
MOTION_BLUR( LPDIRECT3DDEVICE9 pd3dDevice, D3DPRESENT_PARAMETERS* pd3dParameters );
~MOTION_BLUR();
HRESULT Load();
void Invalidate();
void Restore();
//速度マップを作成
void Step1Begin();
void Step1BeginPass();
void Step1SetMatrix( D3DXMATRIX* pMatWorldNew, D3DXMATRIX* pMatWorldOld );
void Step1EndPass();
void Step1End();
//作成した速度マップを参照してサンプリング
void Step2Render();
void CommitChanges();
BOOL IsOK();
LPD3DXEFFECT GetEffect(){ return m_pEffect; };
};
---MotionBlur.cpp---
MOTION_BLUR::MOTION_BLUR( LPDIRECT3DDEVICE9 pd3dDevice, D3DPRESENT_PARAMETERS* pd3dParameters ) : D3D2DSQUARE( pd3dDevice, pd3dParameters )
{
m_pd3dDevice = pd3dDevice;
m_pd3dParameters = pd3dParameters;
m_pEffect = NULL;
}
MOTION_BLUR::~MOTION_BLUR()
{
//SafeReleaseは関数ではなくマクロ
//#define SafeRelease(x) { if(x) { (x)->Release(); (x)=NULL; } }
SafeRelease( m_pEffect );
}
//デバイスがロストしたときにコールする関数
void MOTION_BLUR::Invalidate()
{
if( m_pEffect )
m_pEffect->OnLostDevice();
}
//デバイスがリストアしたときにコールする関数
void MOTION_BLUR::Restore()
{
if( m_pEffect )
m_pEffect->OnResetDevice();
}
HRESULT MOTION_BLUR::Load()
{
D3DCAPS9 caps;
HRESULT hr;
m_pd3dDevice->GetDeviceCaps( &caps );
if( caps.VertexShaderVersion >= D3DVS_VERSION( 1, 1 ) && caps.PixelShaderVersion >= D3DPS_VERSION( 3, 0 ) )
{
hr = D3D2DSQUARE::Load();
if( FAILED( hr ) )
return -1;
//シェーダーの初期化
LPD3DXBUFFER pErr = NULL;
hr = D3DXCreateEffectFromFile( m_pd3dDevice, _T("MotionBlur.fx"), NULL, NULL, 0, NULL, &m_pEffect, &pErr );
if( FAILED( hr ) )
return -2;
m_pTechnique = m_pEffect->GetTechniqueByName( "TShader" );
m_pWVPNew = m_pEffect->GetParameterByName( NULL, "m_WVPNew" );
m_pWVPOld = m_pEffect->GetParameterByName( NULL, "m_WVPOld" );
m_pROnly = m_pEffect->GetParameterByName( NULL, "m_ROnly" );
m_pEffect->SetTechnique( m_pTechnique );
}
else
{
return -3;
}
return S_OK;
}
void MOTION_BLUR::Step1Begin()
{
if( m_pEffect )
{
m_pd3dDevice->GetTransform( D3DTS_VIEW, &m_matViewNew );
m_pd3dDevice->GetTransform( D3DTS_PROJECTION, &m_matProj );
m_pEffect->Begin( NULL, 0 );
}
}
void MOTION_BLUR::Step1BeginPass()
{
if( m_pEffect )
{
m_pEffect->BeginPass( 0 );
}
}
//ローカル座標系
void MOTION_BLUR::Step1SetMatrix( D3DXMATRIX* pMatWorldNew, D3DXMATRIX* pMatWorldOld )
{
if( m_pEffect )
{
D3DXMATRIX m;
D3DXVECTOR4 LightDir;
D3DXVECTOR4 v;
//現在のワールド行列で変換
m = (*pMatWorldNew) * m_matViewNew * m_matProj;
m_pEffect->SetMatrix( m_pWVPNew, &m );
//過去のワールド行列で変換
m = (*pMatWorldOld) * m_matViewOld * m_matProj;
m_pEffect->SetMatrix( m_pWVPOld, &m );
m = (*pMatWorldNew) * m_matViewNew * m_matProj;
m._11 = 1.0f; m._22 = 1.0f; m._33 = 1.0f;
m._41 = 0.0f; m._42 = 0.0f; m._43 = 0.0f;
m_pEffect->SetMatrix( m_pROnly, &m );
}
else
m_pd3dDevice->SetTransform( D3DTS_WORLD, pMatWorldNew );
}
void MOTION_BLUR::CommitChanges()
{
if( m_pEffect )
m_pEffect->CommitChanges();
}
void MOTION_BLUR::Step1EndPass()
{
if( m_pEffect )
{
m_pEffect->EndPass();
}
}
void MOTION_BLUR::Step1End()
{
if( m_pEffect )
{
m_pEffect->End();
}
}
void MOTION_BLUR::Step2Render()
{
if( m_pEffect )
{
m_pEffect->Begin( NULL, 0 );
m_pEffect->BeginPass(1);
D3D2DSQUARE::Render();
m_pEffect->EndPass();
m_pEffect->End();
CopyMemory( &m_matViewOld, &m_matViewNew, sizeof( D3DXMATRIX ) );
}
}
BOOL MOTION_BLUR::IsOK()
{
if( m_pEffect )
return TRUE;
return FALSE;
}
速度マップの作成とブラー処理を行うシェーダーの制御クラスです。関数名の頭にStep1とついている関数は速度マップの作成で使用し、Step2とついている関数はブラー処理で使用します。
---Main.cpp---
LPDIRECT3DDEVICE9 m_pd3dDevice = NULL;
D3DPRESENT_PARAMETERS m_d3dParameters;
D3DCAPS9 Caps;
//シーンのメッシュ
//DirectX SDK(December 2004) に添付されているDXUTMesh.cppファイルにあるヘルパークラス群
CDXUTMesh* m_pMeshBack = NULL;
CDXUTMesh* m_pMeshTeapot = NULL;
//シーンのレンダリングイメージ
LPDIRECT3DSURFACE9 m_pBackBufferSurface = NULL;
LPDIRECT3DTEXTURE9 m_pBackBufferTexture = NULL;
//速度マップ
LPDIRECT3DSURFACE9 m_pVelocitySurface = NULL;
LPDIRECT3DTEXTURE9 m_pVelocityTexture = NULL;
//Z値をα成分に出力するランバート拡散照明クラスの宣言(注意２)
LAMBERT17* m_pLambert = NULL;
//モーションブラークラスの宣言
MOTION_BLUR* m_pMotionBlur = NULL;
//スクリーンの解像度
UINT nWidth = 1024;
UINT nHeight = 768;
//太陽の位置ベクトル
D3DXVECTOR4 LightPos = D3DXVECTOR4( 52.0f, 30.0f, -30.0f, 0.0f );
//平行光源の光の方向ベクトル
D3DXVECTOR4 LightDir;
//視点の位置ベクトル
D3DXVECTOR4 EyePos = D3DXVECTOR4( 0.0f, 0.0f, 0.0f, 1.0f );
D3DXMATRIX matWorldTeapotOld, matWorldTeapotNew;
bool RenderOK = false;
int APIENTRY WinMain( HINSTANCE hInstance,
HINSTANCE /*hPrevInstance*/,
LPSTR /*lpCmpLine*/,
INT /*nCmdShow*/)
{
char* AppName = "Tutrial";
MSG msg;
ZeroMemory(&msg, sizeof(MSG));
HWND hWnd = NULL;
WNDCLASSEX wc;
wc.cbSize = sizeof(WNDCLASSEX);
wc.style = CS_VREDRAW | CS_HREDRAW;
wc.lpfnWndProc = (WNDPROC)WndProc;
wc.cbClsExtra = 0;
wc.cbWndExtra = sizeof(DWORD);
wc.hCursor = LoadCursor(NULL, IDC_ARROW);
wc.hIcon = NULL;
wc.hIconSm = NULL;
wc.lpszMenuName = NULL;
wc.lpszClassName = AppName;
wc.hbrBackground = (HBRUSH)GetStockObject( BLACK_BRUSH );
wc.hInstance = hInstance;
RegisterClassEx(&wc);
//****************************************************************
//ここでウィンドウの作成処理
//****************************************************************
//****************************************************************
//ここでDirect3Dの初期化を行う。
//****************************************************************
m_pd3dDevice->GetDeviceCaps(&Caps);
//メッシュのロード
//背景
m_pMeshBack = new CDXUTMesh();
m_pMeshBack->Create( m_pd3dDevice, _T("res\\back.x") );
m_pMeshBack->SetFVF( m_pd3dDevice, D3DFVF_XYZ | D3DFVF_NORMAL | D3DFVF_TEX1 );
//ティーポット
m_pMeshTeapot = new CDXUTMesh();
m_pMeshTeapot->Create( m_pd3dDevice, _T("res\\t-pot.x") );
m_pMeshTeapot->SetFVF( m_pd3dDevice, D3DFVF_XYZ | D3DFVF_NORMAL | D3DFVF_TEX1 );
//Z値をα成分に出力するランバート拡散照明クラスの初期化
m_pLambert = new LAMBERT17( m_pd3dDevice );
m_pLambert->Load();
//モーションブラーシェーダーの初期化
m_pMotionBlur = new MOTION_BLUR( m_pd3dDevice );
m_pMotionBlur->Load();
//平行光源の位置ベクトルから方向ベクトルを計算する
LightDir = D3DXVECTOR4( -LightPos.x, -LightPos.y, -LightPos.z, 0.0f );
D3DXVec3Normalize( (D3DXVECTOR3*)&LightDir, (D3DXVECTOR3*)&LightDir );
RenderOK = true;
//デバイス消失後にリストアする必要があるオブジェクトの初期化
Restore();
::ShowWindow(hWnd, SW_SHOW);
::UpdateWindow(hWnd);
do
{
if( PeekMessage( &msg, 0, 0, 0, PM_REMOVE ) )
{
TranslateMessage(&msg);
DispatchMessage(&msg);
}
else
{
if( MainLoop(hWnd) == FALSE )
DestroyWindow( hWnd );
}
}while( msg.message != WM_QUIT );
UnregisterClass( AppName, hInstance );
return msg.wParam;
}
//デバイスのリセット前に開放すべきオブジェクト
void Invalidate()
{
m_pLambert->Invalidate();
m_pMotionBlur->Invalidate();
SafeRelease( m_pBackBufferTexture );
SafeRelease( m_pBackBufferSurface );
SafeRelease( m_pVelocityTexture );
SafeRelease( m_pVelocitySurface );
}
//デバイスのリセット後に初期化すべきオブジェクト
void Restore()
{
m_pLambert->Restore();
m_pMotionBlur->Restore();
D3DXCreateTexture( m_pd3dDevice,
nWidth,
nHeight,
1,
D3DUSAGE_RENDERTARGET,
D3DFMT_A8R8G8B8,
D3DPOOL_DEFAULT,
&m_pBackBufferTexture );
m_pBackBufferTexture->GetSurfaceLevel( 0, &m_pBackBufferSurface );
D3DXCreateTexture( m_pd3dDevice,
nWidth,
nHeight,
1,
D3DUSAGE_RENDERTARGET,
D3DFMT_A16B16G16R16F, //速度マップは精度を上げないと正しくレンダリングできない
D3DPOOL_DEFAULT,
&m_pVelocityTexture );
m_pVelocityTexture->GetSurfaceLevel( 0, &m_pVelocitySurface );
//固定機能パイプラインライティングを設定する
D3DLIGHT9 Light;
ZeroMemory(&Light, sizeof(D3DLIGHT9));
Light.Type = D3DLIGHT_DIRECTIONAL;
Light.Direction = D3DXVECTOR3( LightDir.x, LightDir.y, LightDir.z );
Light.Ambient = D3DXCOLOR( 1.0f, 1.0f, 1.0f, 1.0f );
Light.Diffuse = D3DXCOLOR( 1.0f, 1.0f, 1.0f, 1.0f );
Light.Specular = D3DXCOLOR( 0.0f, 0.0f, 0.0f, 0.0f );
m_pd3dDevice->SetLight(0, &Light);
m_pd3dDevice->LightEnable(0, TRUE);
D3DMATERIAL9 Material;
ZeroMemory( &Material, sizeof( Material ) );
Material.Diffuse.r = 1.0f;
Material.Diffuse.g = 1.0f;
Material.Diffuse.b = 1.0f;
Material.Diffuse.a = 1.0f;
m_pd3dDevice->SetMaterial( &Material );
}
//メッセージループからコールされる関数
BOOL MainLoop( HWND HWnd )
{
HRESULT hr;
//レンダリング不可能
if( RenderOK == false )
{
hr = m_pd3dDevice->TestCooperativeLevel();
switch( hr )
{
//デバイスは消失しているがReset可能
case D3DERR_DEVICENOTRESET:
//開放
Invalidate();
//デバイスをリセットする
hr = m_pd3dDevice->Reset( &m_d3dParameters );
switch( hr )
{
//デバイスロスト
case D3DERR_DEVICELOST:
break;
//内部ドライバーエラー
case D3DERR_DRIVERINTERNALERROR:
return FALSE;
break;
//メソッドの呼び出しが無効です
case D3DERR_INVALIDCALL:
return FALSE;
break;
case S_OK:
//初期化
Restore();
RenderOK = true;
}
break;
}
}
//レンダリング可能
else
{
D3DXMATRIX matProj, matView, matWorld;
m_pd3dDevice->BeginScene();
//射影座標変換
D3DXMatrixPerspectiveFovLH( &matProj,
D3DX_PI/4.0f,
4.0f / 3.0f,
30.0f,
580.0f );
m_pd3dDevice->SetTransform( D3DTS_PROJECTION, &matProj );
//ビュー座標変換
//毎フレーム、カメラを回転させる
static float y = 0.0f;
y+=1.0f;
D3DXMATRIX matViewTranslation, matViewRotationY;
D3DXMatrixTranslation( &matViewTranslation, 0.0f, -10.0f, -100.0f );
D3DXMatrixRotationY( &matViewRotationY, D3DXToRadian( y ) );
matView = matViewTranslation * matViewRotationY;
m_pd3dDevice->SetTransform( D3DTS_VIEW, &matView );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_MINFILTER, D3DTEXF_LINEAR );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_MAGFILTER, D3DTEXF_LINEAR );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_MIPFILTER, D3DTEXF_NONE );
//ティーポットを平行移動したりする
//Pos変数の更新は DirectInput を使用したりするが、その辺は自分で実装すること
static D3DXVECTOR3 Pos = D3DXVECTOR3( -15.0f, 1.0f, 150.0 );
D3DXMatrixTranslation( &matWorldTeapotNew, Pos.x, Pos.y, Pos.z );
//バックバッファの初期化
m_pd3dDevice->Clear( 0L,
NULL,
D3DCLEAR_TARGET | D3DCLEAR_ZBUFFER,
0x0,
1.0f,
0L
);
//****************************************************************
// (STEP1) シーンをレンダーターゲットサーフェイスにレンダリングする.
//****************************************************************
LPDIRECT3DSURFACE9 OldSurface = NULL;
m_pd3dDevice->GetRenderTarget( 0, &OldSurface );
m_pd3dDevice->SetRenderTarget( 0, m_pBackBufferSurface );
m_pd3dDevice->Clear( 0L,
NULL,
D3DCLEAR_TARGET | D3DCLEAR_ZBUFFER,
0x0,
1.0f,
0L
);
//地面
m_pLambert->Begin();
D3DXMatrixIdentity( &matWorld );
m_pLambert->SetMatrix( &matWorld, &LightDir );
m_pd3dDevice->SetTexture( 0, m_pMeshBack->m_pTextures[0] );
m_pLambert->SetAmbient( 0.0f );
m_pLambert->BeginPass();
m_pMeshBack->m_pLocalMesh->DrawSubset( 0 );
m_pLambert->EndPass();
//空
m_pd3dDevice->SetTexture( 0, m_pMeshBack->m_pTextures[1] );
m_pLambert->SetAmbient( 1.0f );
m_pLambert->BeginPass();
m_pMeshBack->m_pLocalMesh->DrawSubset( 1 );
m_pLambert->EndPass();
m_pLambert->End();
//ティーポット
m_pLambert->Begin();
m_pLambert->SetMatrix( &matWorldTeapotNew, &LightDir );
m_pd3dDevice->SetTexture( 0, m_pMeshTeapot->m_pTextures[0] );
m_pLambert->SetAmbient( 0.1f );
m_pLambert->BeginPass();
m_pMeshTeapot->m_pLocalMesh->DrawSubset( 0 );
m_pLambert->EndPass();
m_pLambert->End();
m_pd3dDevice->SetRenderTarget( 0, OldSurface );
SafeRelease( OldSurface );
//****************************************************************
// (STEP2) 速度マップの作成
//****************************************************************
m_pd3dDevice->GetRenderTarget( 0, &OldSurface );
m_pd3dDevice->SetRenderTarget( 0, m_pVelocitySurface );
m_pd3dDevice->Clear( 0L,
NULL,
D3DCLEAR_TARGET | D3DCLEAR_ZBUFFER,
0x0,
1.0f,
0L
);
//地面
m_pMotionBlur->Step1Begin();
D3DXMatrixIdentity( &matWorld );
m_pMotionBlur->Step1SetMatrix( &matWorld, &matWorld );
m_pMotionBlur->Step1BeginPass();
m_pMeshBack->m_pLocalMesh->DrawSubset( 0 );
m_pMotionBlur->Step1EndPass();
//空
m_pMotionBlur->Step1SetMatrix( &matWorld, &matWorld );
m_pMotionBlur->Step1BeginPass();
m_pMeshBack->m_pLocalMesh->DrawSubset( 1 );
m_pMotionBlur->Step1EndPass();
//ティーポット
m_pMotionBlur->Step1SetMatrix( &matWorldTeapotNew, &matWorldTeapotOld );
m_pMotionBlur->Step1BeginPass();
m_pMeshTeapot->m_pLocalMesh->DrawSubset( 0 );
m_pMotionBlur->Step1EndPass();
m_pMotionBlur->Step1End();
m_pd3dDevice->SetRenderTarget( 0, OldSurface );
SafeRelease( OldSurface );
//****************************************************************
// (STEP3) 速度マップを参照しサンプリング
//****************************************************************
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_MINFILTER, D3DTEXF_POINT );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_MAGFILTER, D3DTEXF_POINT );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_MIPFILTER, D3DTEXF_NONE );
m_pd3dDevice->SetSamplerState( 1, D3DSAMP_MINFILTER, D3DTEXF_POINT );
m_pd3dDevice->SetSamplerState( 1, D3DSAMP_MAGFILTER, D3DTEXF_POINT );
m_pd3dDevice->SetSamplerState( 1, D3DSAMP_MIPFILTER, D3DTEXF_NONE );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_ADDRESSU, D3DTADDRESS_CLAMP );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_ADDRESSV, D3DTADDRESS_CLAMP );
m_pd3dDevice->SetRenderState( D3DRS_ZENABLE, D3DZB_FALSE );
m_pd3dDevice->SetTexture( 0, m_pBackBufferTexture );
m_pd3dDevice->SetTexture( 1, m_pVelocityTexture );
m_pMotionBlur->Step2Render();
m_pd3dDevice->SetTexture( 1, NULL );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_ADDRESSU, D3DTADDRESS_WRAP );
m_pd3dDevice->SetSamplerState( 0, D3DSAMP_ADDRESSV, D3DTADDRESS_WRAP );
m_pd3dDevice->SetRenderState( D3DRS_ZENABLE, D3DZB_TRUE );
//現在のトラのワールド行列をコピー
CopyMemory( &matWorldTeapotOld, &matWorldTeapotNew, sizeof( D3DXMATRIX ) );
m_pd3dDevice->EndScene();
hr = m_pd3dDevice->Present( NULL, NULL, NULL, NULL );
//デバイスロストのチェック
switch( hr )
{
//デバイスロスト
case D3DERR_DEVICELOST:
RenderOK = false;
break;
//内部ドライバーエラー
case D3DERR_DRIVERINTERNALERROR:
return FALSE;
break;
//メソッドの呼び出しが無効です
case D3DERR_INVALIDCALL:
return FALSE;
break;
}
}
return TRUE;
}
以上です。
(注意２) 唐突にLAMBERT17クラスが登場しましたが、ライティングをランバート拡散照明で行い、レンダーターゲットの A成分 にシーンのＺ値を出力するシェーダーの制御クラスです。 さんざんやってるので、いちいちソースを書かなくてもいいでしょう。というわけで省略します。
速度マップのフォーマットにD3DFMT_A16B16G16R16Fを使用しました。精度をあげないと正しくレンダリングできないので浮動小数点フォーマットを使用しましたが、 そのせいで実行できる環境が限定されるかもしれません。動作しない時はD3DFMT_A8R8G8B8に修正してみてください。
今回はシェーダー内でＺ値を参照します。これやると必ずといっていいほどはまるのがＺ値の精度が低いのが原因で、正しくレンダリングできないことです。 正しくレンダリングできないときはＺ値の値を適当なサーフェイスに出力してみてください。その結果、全体が真っ白くなったりしたらＺ値の精度が落ちてるので、 シーンの大きさを考慮し、射影変換行列の前面クリップ面と背面クリップ面の値を正しく調整してください。
最後に「GameWatch」の「ロストプラネット」の記事を参照すると他にもやってることがあります。縮退ポリゴンはモデリングの話なので ここでは問題にしませんが、LOD的概念による最適化は重要でしょう。ここではスルーしてますけど、実際のゲームで実装する場合は考慮すべきでしょうな。